I was unable to figure out a way to get the MP3 and FLAC files in separate locations when using EAC and Mareo. I ultimately realized I preferred a two-step process:
Step 1: Rip & FLAC encode all CDs
Step 2: Batch transcode all FLACs to MP3, WMA, etc.
This was optimal for me since Step 1 is the most time-consuming and Step 2 slows down Step 1. Moreover, it's easy to kickoff Step 2 to run overnight.
Assuming you wish to batch convert an existing directory full of FLACs to MP3 using LAME you can use the following script (Win32). Just paste it into a .cmd or .bat file, modify the five environment variables to match your system, modify the LAME parameters to suit your needs, and run it.
Notes:
* This script only works with a single level hierarchy (all FLACs in %FLACDIR% with no sub-directories
* The MP3 files won't have ID3 tags
Hope this helps,
Keith
@ECHO OFF
SET FLACDIR=D:\FLAC
SET MP3DIR=D:\MP3
SET FLACEXE=D:\util\flac.exe
SET LAMEEXE=D:\util\lame.exe
SET LOGFILE=D:\Logs\FLACtoLAME.log
subst q: %FLACDIR%
subst r: %MP3DIR%
FOR /R "q:\" %%I IN (*.flac) DO (
IF NOT EXIST "r:%%~pI" (
mkdir "r:%%~pI"
ECHO Created r:%%~pI
ECHO Created r:%%~pI>>"%LOGFILE%"
)
IF NOT EXIST "r:%%~pnI.mp3" (
ECHO Creating r:%%~pnI.mp3
"%FLACEXE%" -d -c -s "%%I" | "%LAMEEXE%" --alt-preset extreme --silent - "r:%%~pnI.mp3"
ECHO Created r:%%~pnI.mp3>>"%LOGFILE%"
) ELSE (
ECHO Exists r:%%~pnI.mp3
ECHO Exists r:%%~pnI.mp3>>"%LOGFILE%"
)
)
subst q: /d
subst r: /d
SET FLACDIR=
SET MP3DIR=
SET FLACEXE=
SET LAMEEXE=
